VB6 Ms. Access: Menampilkan List Table yang ada Pada Database Access - Part 1


Terinspirasi dari versi VB.NET nya, sekarang Rani coba bikin versi VB6.
Pastikan jenis file database Ms. Access berbentuk .mdb dan berikut bentuk database yang akan kita gunakan:
Kemudian kita siapkan UI dengan menambahkan sebuah listbox dan datagrid pada form.
Kita akan menggunakan koneksi ADO, karena itu sebelum lanjut ke code mari kita tambahkan dulu reference nya dengan klik menu Project --> Reference...
Centang pada Microsoft ActiveX Data Object 2.7 Libary kemudian klik OK.
Pada jendela code, kita mulai dengan Option Explicit dan mendeklarasikan variable yang dibutuhkan.
Option Explicit
Dim oConn As New ADODB.Connection

Dim rsData As New ADODB.Recordset 
Dim strConn As String 
Dim SQL As String

Variable string strConn untuk menyimpan connection string. Kita beri nilai saat event Form_Load.
Private Sub Form_Load()
strConn = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
          "Data Source=" & App.Path & "\latihan.mdb;" & _
          "Persist Security Info=False"
End Sub


Kemudian kita buat sub untuk membuka koneksi:
Sub Open_Connection()
Set oConn = New ADODB.Connection
oConn.ConnectionString = strConn
oConn.Open
End Sub


Sub untuk menampilkan list nama tabel ke dalam listbox.
Private Sub ListTables()
Open_Connection
Dim rs As ADODB.Recordset

List1.Clear
Set rs = oConn.OpenSchema(adSchemaTables, _
         Array(Empty,
Empty, Empty, "Table"))
Do While Not rs.EOF
    List1.AddItem rs!TABLE_NAME
    rs.MoveNext
Loop

rs.Close
oConn.Close

List1.ListIndex = 0
End Sub


Lalu panggil sub tersebut di event form load (perubahan di highlight pink)
Private Sub Form_Load()
strConn = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
          "Data Source=" & App.Path & "\latihan.mdb;" & _
          "Persist Security Info=False"

ListTables
End Sub

Procedure selanjutnya adalah untuk menampilkan data table item list terpilih di datagrid.
Sub Load_Data(TableName As String)
Open_Connection
Set rsData = New ADODB.Recordset
SQL = "SELECT * FROM " & TableName
With rsData
    .CursorLocation = adUseClient
    .Open SQL, oConn, adOpenDynamic, adLockOptimistic
    .ActiveConnection = Nothing
End With
Set DataGrid1.DataSource = rsData
oConn.Close
End Sub

Kita akan memanggil sub procedure yang baru kita buat di event List1 Click.
Private Sub List1_Click()
Load_Data List1.Text
End Sub

Kode selengkapnya dan runtime ada di Part 2

Click here if you like this article.


Post a Comment

0 Comments